100 ' LNET.BAS     Dan Maguire  AC6LA
110 '
120 ' Calculate low-pass L network values (assumed 50 ohm input).
130 ' See paper by R. F. White, Antenna Compendium Vol 2, pg 187.
140 '
150 COLOR 7,1
160 CLS
170 PRINT "--- LNET ---";
180   PRINT "   Low-pass L network values (50 ohm input)"
190 PRINT
200 '
210 PRINT "R,";CHR$(241);"X of load in ohms";
220 INPUT ""; RS, XS
230 INPUT "Frequency in MHz"; F
240 INPUT "Input power in watts"; PWR
250 '
260 '  Find parallel equivalent of load.
270 '
280 RP = RS + XS*XS / RS
290 IF XS <> 0 THEN XP = XS + RS*RS / XS  ELSE  XP = 1.7E+38
300 '
310 IF RP => 50 THEN GOTO 480
320 '
330 '  Case 1.
340 '
350 N = SQR(50 * RS)
360 T = 50 / RS
370 Q = SQR(T - 1)
380 SQR1T = SQR(1 / T)
390 P = 1.570796 - ATN(SQR1T/SQR(1-SQR1T*SQR1T))  '= ARCCOS(SQR1T)
400 XA = N * SIN(P) / (SQR(1/T) * COS(P) - 1)
410 XB = N * SIN(P)
420 X2 = -(N*N) / XB
430 X3 = -(N*N) / XA
440 X3 = X3 - XS
450 XSER = X3
460 XSHU = X2
470 GOTO 630
480 '
490 '  Case 4.
500 '
510 N = SQR(RP * 50)
520 T = RP / 50
530 Q = SQR(T - 1)
540 IF RP = 50 THEN XA = -XP:  XB = 0:  GOTO 600
550 SQR1T = SQR(1 / T)
560 P = 1.570796 - ATN(SQR1T/SQR(1-SQR1T*SQR1T))  '= ARCCOS(SQR1T)
570 XA = N * SIN(P) / (SQR(1/T) * COS(P) - 1)
580 XB = N * SIN(P)
590 XA = 1 / (1/XA - 1/XP)
600 XSER = XB
610 XSHU = XA
620 '
630 PRINT
640 PRINT "Series X ="; USING "+####.##"; XSER;
650   UH = XSER / (6.283185 * F)
660   PRINT " ohms     L ="; USING "###.##"; UH;:  PRINT " uH"
670 PRINT "Shunt  X ="; USING "+####.##"; XSHU;
680 IF XSHU => 0 THEN GOTO 720
690   PF = -1000000! / (6.283185 * F * XSHU)
700   PRINT " ohms     C ="; USING "######"; PF;:  PRINT " pF";
710     GOTO 750
720   UH = XSHU / (6.283185 * F)
730   PRINT " ohms     L ="; USING "###.##"; UH;:  PRINT " uH";
740   '
750   IF RP => 50 THEN PRINT "     On -load- side":  GOTO 770
760   PRINT "     On -input- side"
770 PRINT "System Q ="; USING "###.#"; Q
780 '
790 '  Find voltage across shunt element at given input power.
800 '  See Devoldere "Low Band DXing", pg 6-8.
810 '
820 IF RP => 50 THEN GOTO 870
830 'Input side.
840   ERMS = SQR(PWR * 50)
850   EPEAK = ERMS * 1.414
860   GOTO 910
870 'Load side.
880   Z = SQR(RS*RS + XS*XS)
890   ERMS = SQR(PWR / RS) * Z
900   EPEAK = ERMS * 1.414
910 PRINT "Voltage across shunt element =";
920   PRINT USING "####.##"; ERMS;:  PRINT " (rms),";
930     PRINT USING "####.##"; EPEAK;:  PRINT " (peak)"
940 '
950 PRINT
960 INPUT "Repeat (y/[n])"; RPT$
970 IF RPT$ = "y" THEN PRINT:  GOTO 210
980 '
990 COLOR 7,0: CLS: SYSTEM